ArtNet node discovered in QLC but no output to pixels

[D2Jay]

Hello, I have been trying to get an Arduino ArtNet node to work. I connected everything correctly it seems, as when I load the sketch, the LEDs run a quick test sequence. When I set up the IP settings in QLC, everything seemed fine. QLC said that the node was discovered though I am not getting any output to the pixels. I am currently using an Arduino UNO running IDE 1.8.7 with an ethernet shield connected to WS2811 LEDs. I am fairly new to this and any help would be appreciated. Thanks.

[GGGss]

You are sure that the Arduino is sending signals to your LED's in the first place? Or is that your statement 'load the sketch, the LEDs run a quick test sequence'?
Then manually configure a network address in your Arduino. (Don't rely on DHCP in test environments - you simply have to be sure) 10.x.x.x range with mask 255.0.0.0 as per (old) Artnet convention.
On your QLC+ host you will also arrange an IP in the same range (10.x.x.x)
From your QLC+ host - ping to the Arduino - just making sure it can see the Arduino.
Then ... you can start configuring the QLC+ artnet settings conform to the above settings.

Don't forget that Artnet is 10-based so universe 1 is in fact 0; channel 1 is 0...

[D2Jay]

It should be. After uploading the sketch for the ArtNet node, the LEDs light up. Though I cannot output from QLC. I have tried numerous IP settings and subnet masks. Everything manual. Here is the code.

Code: Select all

/*
This example will receive multiple universes via Artnet and control a strip of ws2811 leds via 
Adafruit's NeoPixel library: https://github.com/adafruit/Adafruit_NeoPixel
This example may be copied under the terms of the MIT license, see the LICENSE file for details
*/

#include <Artnet.h>
#include <Ethernet.h>
#include <EthernetUdp.h> 
#include <SPI.h>
#include <Adafruit_NeoPixel.h>

// Neopixel settings
const int numLeds = 50; // change for your setup
const int numberOfChannels = numLeds * 3; // Total number of channels you want to receive (1 led = 3 channels)
const byte dataPin = 5;
Adafruit_NeoPixel leds = Adafruit_NeoPixel(numLeds, dataPin, NEO_GRB + NEO_KHZ800);

// Artnet settings
Artnet artnet;
const int startUniverse = 0; // CHANGE FOR YOUR SETUP most software this is 1, some software send out artnet first universe as 0.

// Check if we got all universes
const int maxUniverses = numberOfChannels / 512 + ((numberOfChannels % 512) ? 1 : 0);
bool universesReceived[maxUniverses];
bool sendFrame = 1;
int previousDataLength = 0;

// Change ip and mac address for your setup
byte ip[] = {10,0,0,2};
byte mac[] = {0x08, 0xE9, 0xE5, 0x00, 0x69, 0xEC}; // make sure this is different than any other mac address in your network

void setup()
{
  Serial.begin(115200);
  artnet.begin(mac, ip);
  leds.begin();
  initTest();

  // this will be called for each packet received
  artnet.setArtDmxCallback(onDmxFrame);
}

void loop()
{
  // we call the read function inside the loop
  artnet.read();
}

void onDmxFrame(uint16_t universe, uint16_t length, uint8_t sequence, uint8_t* data)
{
  sendFrame = 1;
  // set brightness of the whole strip 
  if (universe == 15)
  {
    leds.setBrightness(data[0]);
    leds.show();
  }

  // Store which universe has got in
  if ((universe - startUniverse) < maxUniverses)
    universesReceived[universe - startUniverse] = 1;

  for (int i = 0 ; i < maxUniverses ; i++)
  {
    if (universesReceived[i] == 0)
    {
      //Serial.println("Broke");
      sendFrame = 0;
      break;
    }
  }

  // read universe and put into the right part of the display buffer
  for (int i = 0; i < length / 3; i++)
  {
    int led = i + (universe - startUniverse) * (previousDataLength / 3);
    if (led < numLeds)
      leds.setPixelColor(led, data[i * 3], data[i * 3 + 1], data[i * 3 + 2]);
  }
  previousDataLength = length;     
  
  if (sendFrame)
  {
    leds.show();
    // Reset universeReceived to 0
    memset(universesReceived, 0, maxUniverses);
  }
}

void initTest()
{
  for (int i = 0 ; i < numLeds ; i++)
    leds.setPixelColor(i, 127, 0, 0);
  leds.show();
  delay(500);
  for (int i = 0 ; i < numLeds ; i++)
    leds.setPixelColor(i, 0, 127, 0);
  leds.show();
  delay(500);
  for (int i = 0 ; i < numLeds ; i++)
    leds.setPixelColor(i, 0, 0, 127);
  leds.show();
  delay(500);
  for (int i = 0 ; i < numLeds ; i++)
    leds.setPixelColor(i, 0, 0, 0);
  leds.show();
}

[GGGss]

looking into the code there is an instruction looking for universe 15 channel 0 which sets the intensity of your panel...
This should have given you a clue.

Code: Select all

void onDmxFrame(uint16_t universe, uint16_t length, uint8_t sequence, uint8_t* data)
{
  sendFrame = 1;
  // set brightness of the whole strip 
  if (universe == 15)
  {
    leds.setBrightness(data[0]);
    leds.show();
  }
 

Id suggest as a test that you change the code (make a backup first)
add before the if instruction:
leds.setBrightness(255);